***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 20, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt ES2G A K
.param
+vc0 = 1.223e-9		 vc1 = 2.053e-11	 vc2 = 1.000e-0		
+vc3 = 8.081e-11	 vc4 = 1.495e-2
+tc1 = 1.051e-2		 tc2 = 3.391e-2		 tc3 = 6.651e-2		tc4 = 3.081e-2
+tc5 = 1.031e-2		 tc6 = 1.821e-2
.func ir0(v) {(vc0)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.func ir1(v) {(vc1*v^vc2)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func ir2(v) {(vc3*exp(vc4*v))*(1.0+tc5*(temp-25)*exp(tc6*(temp-25)))}
.func irexp(v) {ir0(v)+ir1(v)+ir2(v)}
g1 K A value = {irexp(v(K,A))}
d1 A K sbd
.model sbd d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.686e-10	   n = 1.218		  rs = 6.377e-2		ikf = 1.033e-2
+ibv = 0.1e-3		 nbv = 1	  	  bv = 440
***** capacitance parameter *****
+cjo = 4.138e-11  	   m = 3.399e-1		  vj = 2.644e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 9.786e-1		 xti = 3
+trs1 = -1.071e-3	trs2 = -2.084e-5	tikf = 1.186e-2
.ends ES2G
*$
